{@ME.FORMAT                                                                      }
{****************************************************************************}
{                ---  Mult-Edit macros for assembler ---                     }
{****************************************************************************}

$MACRO_FILE ASM;
{******************************************************************************}
{                                MULTI-EDIT MACRO                              }
{                                                                              }
{Name: ASM_IND                                                                 }
{                                                                              }
{Description:  This macro will capitalize all characters on the current line   }
{up to the end of the line, or  the ";" comment delimiter, whichever comes     }
{first.  Then it will perform a carriage return.                               }
{                                                                              }
{               (C) Copyright 1988 by American Cybernetics, Inc.               }
{******************************************************************************}

$MACRO ASM_IND;
	Def_Int(Temp_Integer);
	If (AT_EOL) Then
		Temp_Integer := XPos(';',Get_Line,1);
		IF Not(Temp_Integer) THEN
			Temp_Integer := Length(Get_Line);
		END;
		IF (Temp_Integer) THEN
			Put_Line(Caps(Copy(Get_Line,1,Temp_Integer)) + Copy(Get_Line,Temp_Integer + 1,254));
		END;
	End;
	Cr;
END_MACRO;

$MACRO PROC;
	def_str(tstr);

	Goto_Col(1);
	tstr := Get_Word('');
	text(' PROC FAR');
	Goto_Col(1);
	Undent;
	CR;
	UP;
	text('PUBLIC ' + tstr);
	down;
	down;
	goto_Col(1);
	indent;
	text('SAVE_BP');
	CR;
	CR;
	Text('RESTORE_BP');
	CR;
	TEXT('RET');
	CR;
	Goto_COL(1);
	Text(TSTR + ' ENDP');
	CR;
	UP;
	UP;
	UP;
	UP;
	GOTO_COL(1);
	INDENT;

END_MACRO;
